Cronos-Crypter

Created the Saturday 17 August 2024. Updated 3 months ago.

Cronos-Crypter is an open-source crypter publicly available on GitHub. The crypter applies AES encryption or XOR obfuscation to a selected payload before storing it as a .NET resource of a final generated .NET executable payload. Cronos-Crypter contains multiple capabilties for persistence and defense evasion. An operator may select persistence via a Windows Registry autorun key or a Scheduled Task. An operator may also select for decrypted payloads to be injected into a newly spawned copy of itself or regasm.exe. To further evade defenses, the operator may also specify to introduce a sleep delay, bypass AMSI controls, and avoid execution within virtual machine environments.

Technique Identifier

U1437

Detection Rules

import "pe"
import "dotnet"

rule MAL_Cronos_Crypter_Strings {
    meta:
        description = "Detects Cronos Crypter based on strings found in file."
        author = "Tony Lambert"
        reference = "0eb4874937a6a37665e74fcd90413b0d4161659a0226b1ebf667b954b41b1012"
        date = "2024-03-17"
    strings:
        $s1 = "Cronos-Crypter" ascii wide
        $s2 = "Rfc2898DeriveBytes" ascii wide
        $s3 = "RijndaelManaged" ascii wide
    condition:
        pe.is_pe and all of them
}

rule MAL_Cronos_Crypter_Salt {
    meta:
        description = "Detects Cronos Crypter based encryption salt value and string that should be seen in memory."
        author = "Tony Lambert"
        reference = "0eb4874937a6a37665e74fcd90413b0d4161659a0226b1ebf667b954b41b1012"
        date = "2024-03-17"
    strings:
        $s1 = "Cronos-Crypter" ascii wide
        $salt = {1A 14 CA EA 88 7B 45 2F}
    condition:
        all of them
}

rule MAL_Cronos_Crypter_Assembly_Name {
    meta:
        description = "Detects Cronos Crypter based on .NET assembly name."
        author = "Tony Lambert"
        reference = "0eb4874937a6a37665e74fcd90413b0d4161659a0226b1ebf667b954b41b1012"
        date = "2024-03-17"
    condition:
        dotnet.assembly.name startswith "Cronos-Crypter"
}

Additional Resources

External Links

The resources provided below are associated links that will give you even more detailed information and research on current evasion technique. It is important to note that, while these resources may be helpful, it is important to exercise caution when following external links. As always, be careful when clicking on links from unknown sources, as they may lead to malicious content.

GitHub - TalosSec/Cronos-Crypter: Cronos Crypter is an simple example of crypter created for educational purposes.

Cronos-Crypter

Technique Identifier

Detection Rules

Additional Resources

External Links

Subscribe to our Newsletter